用51單片機對7113初始化和控制

　　SAA7113的初始化就是對寄存器配置合適的參數，使其能夠有符合要求的輸出。寄存器配置通過I2C總線來進行，很多可以控制I2C總線的器件都可以作為主器件對7113進行初始化，這里介紹用51單片機初始化7113的例子。

　　51單片機和7113的硬件連接非常簡單，只要把單片機的兩個I/O口(如P1.0、P1.0)直接和7113的SCL、SDA管腳相連，再加上上拉電阻即可。

　　用單片機初始化7113的主要任務是程序的編寫，首先要熟悉I2C總線協議，根據I2C總線的原理寫出啟動、停止、應答信號等的子程序，由子程序再寫出發送、接收1個字節的程序，然后根據7113的寄存器操作格式寫出讀寫寄存器的程序，最后根據以上的子程序寫出初始化7113的程序段。

　　對7113的控制一般是改變色度、亮度等指標以及輸出管腳的輸出信號，這可以通過修改相應寄存器的值來完成，程序上寫出“讀寫命令”即可。

　　下面以程序段的形式給出初始化SAA7113以及讀寫寄存器的具體例子，以供參考。

　　SDA　BIT　P1.0

　　SCL　BIT　P1.1

　　I2C_ERROR　BIT　00H　;I2C總線數據傳輸出錯標志

　　DeviceaddressW　EQU　4AH　;7113器件地址+寫

　　DeviceaddressR　EQU　4BH　;7113器件地址+讀

　　Subaddress　EQU　4DH　;7113寄存器地址字節在單片機中的存放地址

　　DATA_I2C　EQU　50H　;設置寫入或讀出數據在單片機中的存放地址

　　;*************啟動**************

　　I2C_START:　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　CLR　SDA

　　NOP

　　CLR　SCL

　　RET

　　;***************停止**************

　　I2C_STOP:　CLR　SDA

　　NOP

　　SETB　SCL

　　NOP

　　SETB　SDA

　　NOP

　　RET

　　;************送應答位************

　　SEND_ACK:　CLR　SCL

　　NOP

　　CLR　SDA

　　NOP

　　SETB　SCL

　　NOP

　　?NOP

　　CLR　SCL

　　NOP

　　SETB　SDA

　　RET

　　;***********送非應答位***********

　　SEND_NOACK: SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　CLR　SCL

　　NOP

　　RET

　　;***********檢查應答位************

　　CHECK_ACK: NOP

　　CLR　SCL

　　NOP

　　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　MOV　C, SDA

　　MOV　I2C_ERROR, C

　　CLR　SCL

　　NOP

　　RET

　　;*******發送1字節數據，待送數據在A中******

　　I2C_SEND_1BYTE:

　　MOV　R0, #8

　　SEND100: RLC　A

　　MOV　SDA,　C

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　CLR　SCL

　　DJNZ　R0, SEND100

　　RET

　　;*******接收1字節數據，接收數據放在A中*****

　　I2C_RECEIVE_1BYTE:

　　MOV　R0,　#8

　　RECV100:　SETB　SDA

　　NOP

　　SETB　SCL

　　NOP

　　NOP

　　NOP

　　MOV　C,　SDA

　　CLR　SCL

　　RLC　A

　　DJNZ　R0,　RECV100

　　RET

　　;*******通過I2C總線向某一寄存器寫入一個字節數據*********

　　I2C_WRITE:　ACALL　I2C_START　;發啟動信號

　　MOV　A， # DeviceaddressW ;調7113地址+寫

　　ACALL　I2C_SEND_1BYTE　;發送7113地址及“寫”命令

　　ACALL　CHECK_ACK　;檢查7113的應答信號

　　JNB　I2C_ERROR, WR200　;應答正確，繼續

　　WR100:　ACALL　I2C_STOP　;應答不對，返回

　　RET

　　WR200:　MOV　A, Subaddress　;調寄存器地址

　　ACALL　I2C_SEND_1BYTE　;發送寄存器地址

　　ACALL　CHECK_ACK　;檢查7113的應答信號

　　JB　I2C_ERROR, WR100　;應答不對，返回

　　MOV　A, DATA_I2C　;調準備寫入的數據

　　ACALL　I2C_SEND_1BYTE　;發送數據字節

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, WR100

　　ACALL　I2C_STOP　;發停止信號

　　RET

　　;*******通過I2C總線讀出某一寄存器的數據*********

　　I2C_READ:　ACALL　I2C_START

　　MOV　A, # DeviceaddressW　;調7113地址，寫入

　　ACALL　I2C_SEND_1BYTE

　　ACALL　CHECK_ACK

　　JNB　I2C_ERROR, RD200

　　RD100:　ACALL　I2C_STOP

　　RET

　　RD200:　MOV　A, Subaddress　;調要讀的寄存器地址

　　ACALL　I2C_SEND_1BYTE　; 發送寄存器地址字節

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, RD100

　　ACALL　I2C_START　;重發起動信號

　　MOV　A, # DeviceaddressR　;調7113地址，讀

　　ACALL　I2C_SEND_1BYTE

　　ACALL　CHECK_ACK

　　JB　I2C_ERROR, RD100

　　ACALL　I2C_RECEIVE_1BYTE ;接收讀出的數據

　　MOV　DATA_I2C,A　;讀出數據轉存

　　ACALL　SEND_NOACK　;發送非應答位

　　ACALL　I2C_STOP　;停止

　　RET

　　;***************初始化7113，配置各寄存器************************

　　INIT_SAA7113:　MOV　DPTR, #SAA7113_Subaddress

　　MOV　R7, #28

　　INIT100:　MOV　A, #0

　　MOV　C A, @A+DPTR

　　MOV　Subaddress,　A　;調寄存器地址

　　MOV　A,#28

　　MOVC　A, @A+DPTR

　　MOV　DATA_I2C, A　;調寄存器配置數據

　　INC DPTR

　　ACALL　I2C_WRITE　;配置1個寄存器

　　JB　I2C_ERROR, INIT200

　　DJNZ　R7,INIT100

　　INIT200:　RET

　　;***************SAA7113寄存器初始化配置數據**********************

　　SAA7113_Subaddress:

　　DB 01H,02H,03H,04H,05H,06H,07H,08H,09H,0AH,0BH,0CH,0DH,0EH

　　DB 0FH,10H,11H,12H,13H,15H,16H,17H,40H,58H,59H,5AH,5BH,5EH

　　;共28個

　　I2C_REG_VALUE_AI11:

　　DB 08H,0C0H,33H,00H,00H,0EBH,0E0H,0B8H,01H,7EH,46H,43H,01H,01H

　　DB 0FH,00H,0CH,0A7H,00H,00H,00H,00H,02H,00H,54H,07H,80H,00H

　　;*************對SAA7113某一寄存器的改寫與讀出*******************

　　WRITE_READ:　MOV　Subaddress, #0AH　; 設寄存器地址為0AH

　　MOV　DATA_I2C, #88H　;改寄存器的值為88H

　　ACALL　I2C_WRITE　;改寫

　　ACALL　I2C_READ　;讀出