很多人不知道怎么看著時(shí)序圖寫程序，下面結(jié)合一個(gè)非標(biāo)準(zhǔn)的I2C器件，教大家如何寫一個(gè)高效的IO模擬I2C時(shí)序。

觀察該時(shí)序，具備I2C的開始信號(hào)，I2C的結(jié)束信號(hào)，I2C的應(yīng)答、非應(yīng)答、響應(yīng)應(yīng)答，以及寫字節(jié)和讀字節(jié)的基本操作時(shí)序。

下面，我們一步一步分析。

1、I2C開始信號(hào)

觀察時(shí)序圖，在SCLK高電平的狀態(tài)下，在SDIO產(chǎn)生一個(gè)下降沿是為開始信號(hào)。

void I2C_Start()
{
  //設(shè)置I2C使用的兩個(gè)引腳為輸出模式
  pinMode(SCLK_PIN, OUTPUT);
  pinMode(SDIO_PIN, OUTPUT);


  //在SCL為高電平的時(shí)候讓SDA產(chǎn)生一個(gè)下降沿是為開始信號(hào)
  digitalWrite(SDIO_PIN, 1);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SDIO_PIN, 0);
}

上述代碼即先將兩個(gè)引腳設(shè)置為輸出模式，然后在SCLK為高電平的時(shí)候在SDIO引腳輸出一個(gè)下降沿。

2、I2C停止信號(hào)

觀察時(shí)序圖，在SCLK為高電平的時(shí)候在SDIO引腳產(chǎn)生一個(gè)上升沿是為停止信號(hào)。

void I2C_Stop()
{
  pinMode(SDIO_PIN, OUTPUT);
  //在SCL為高電平的時(shí)候讓SDA產(chǎn)生一個(gè)上升沿是為停止信號(hào)
  digitalWrite(SDIO_PIN, 0);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SDIO_PIN, 1);
}

這里采用的是Arduino編寫的IO基本操作，你可以替換成任意單片機(jī)的IO操作。

由于整個(gè)過(guò)程SCLK引腳一直是輸出狀態(tài)，所以僅在開始信號(hào)中對(duì)SCLK初始化為輸出模式，而過(guò)程中可能會(huì)修改SDIO的輸入輸出模式，所以其他的函數(shù)開頭都要根據(jù)情況對(duì)SDIO引腳的模式進(jìn)行設(shè)置。

通過(guò)三行代碼實(shí)現(xiàn)在SCLK為高電平的時(shí)候在SDIO產(chǎn)生一個(gè)上升沿，實(shí)現(xiàn)停止信號(hào)。

3、寫字節(jié)操作

接下來(lái)，按照時(shí)序的順序編寫方便認(rèn)讀

I2C的讀寫字節(jié)是這么定義的：當(dāng)時(shí)鐘線為低電平的時(shí)候，允許修改數(shù)據(jù)線的電平狀態(tài)，在時(shí)鐘線為高電平的時(shí)候讀取數(shù)據(jù)線的狀態(tài)。

因?yàn)槭菍懖僮鳎虼宋覀円葘r(shí)鐘線SCLK拉低，再修改SDIO的值，然后拉高時(shí)鐘。拉高后，從機(jī)就會(huì)從總線上讀取SDIO的狀態(tài)，接著一位一位的這么發(fā)送。

void I2C_Write(uint8_t dat)
{
  pinMode(SDIO_PIN, OUTPUT);
  //拉低時(shí)鐘線后可修改數(shù)據(jù)線的狀態(tài)
  digitalWrite(SCLK_PIN, 0); 
  for(int i=0;i<8;i++)
  {
    digitalWrite(SDIO_PIN, (bool)(dat&0x80)); 
    digitalWrite(SCLK_PIN, 1);//在高電平時(shí)候送出數(shù)據(jù)
    dat=dat<<1;
    digitalWrite(SCLK_PIN, 0);//拉低準(zhǔn)備下一個(gè)位的數(shù)據(jù)發(fā)送
  }
}

上述代碼正描述了這一情況：為了保證最后是低電平，這里將SCLK的第一次拉低放到循環(huán)外面，這樣可以用最少的執(zhí)行次數(shù)完成一個(gè)字節(jié)的寫任務(wù)；同時(shí)，結(jié)束完一個(gè)字節(jié)寫入后時(shí)鐘線是低電平狀態(tài)（時(shí)序圖中寫入的第一個(gè)字節(jié)為DeviceID，第二個(gè)字節(jié)為寄存器地址+讀寫位）。

寫完一個(gè)字節(jié)后，從機(jī)會(huì)對(duì)寫入事件進(jìn)行應(yīng)答，這個(gè)時(shí)候主級(jí)可以從總線上讀取應(yīng)答信號(hào)。

4、讀取從機(jī)應(yīng)答引號(hào)

應(yīng)答信號(hào)在寫入完一個(gè)字節(jié)后的低電平后由從機(jī)送出，在時(shí)鐘為高電平的時(shí)候可以讀取出來(lái)，我們注意到寫入自己操作后時(shí)鐘線已經(jīng)是低電平了，因此這個(gè)時(shí)候

只要拉高時(shí)鐘線，接下來(lái)就可以讀取應(yīng)答信號(hào)，讀取完應(yīng)答信號(hào)根據(jù)時(shí)序圖應(yīng)該拉低時(shí)鐘準(zhǔn)備下一個(gè)字節(jié)的寫入。

bool I2C_RACK()
{
  bool ack;
  pinMode(SDIO_PIN, INPUT);


  digitalWrite(SCLK_PIN, 1);//接收應(yīng)答信號(hào)，當(dāng)時(shí)鐘拉高時(shí)候，從機(jī)送出應(yīng)答信號(hào)
  ack = digitalRead(SDIO_PIN);
  digitalWrite(SCLK_PIN, 0);//讀取完應(yīng)答信號(hào)后拉低時(shí)鐘。
  return ack;
}

如上代碼所示，即為接收從機(jī)應(yīng)答，拉高時(shí)鐘，讀取應(yīng)答，再拉低，返回應(yīng)答。如果從機(jī)應(yīng)答了，這里會(huì)讀取到一個(gè)低電平。

后面就是再寫入一個(gè)寄存器+讀寫位的地址，參靠上面的寫入操作。

寫入寄存器地址后，緊跟著又一個(gè)接收從機(jī)應(yīng)答信號(hào)，然后從機(jī)就會(huì)送出數(shù)據(jù)，送出的數(shù)據(jù)分高字節(jié)和低字節(jié)，高低字節(jié)間要有一個(gè)主機(jī)發(fā)送給從機(jī)的應(yīng)答信號(hào)，這樣從機(jī)酒知道主機(jī)收到了數(shù)據(jù)，就會(huì)送出后面的低字節(jié)數(shù)據(jù)。

5、讀字節(jié)操作

注意，前面說(shuō)過(guò)，讀寫都是總線在時(shí)鐘低電平時(shí)候修改數(shù)據(jù)線，在高電平送出。

因此，主機(jī)讀取從機(jī)送來(lái)的數(shù)據(jù)仍然是在高電平時(shí)候讀取。

uint8_t I2C_Read()
{
  uint8_t dat=0;
  pinMode(SDIO_PIN, INPUT);
  for(int i=0;i<8;i++)
  {
    digitalWrite(SCLK_PIN, 1);//讀取數(shù)據(jù)時(shí)候是在時(shí)鐘的高電平狀態(tài)讀取
    dat=dat<<1;
    if(digitalRead(SDIO_PIN))
    {
      dat=dat|1;
    }
    digitalWrite(SCLK_PIN, 0);//拉低時(shí)鐘線準(zhǔn)備下一個(gè)位的讀取
  }
  return dat;
}

操作過(guò)程是將SDIO數(shù)據(jù)線的IO設(shè)置為輸入模式，準(zhǔn)備讀取，然后拉高時(shí)鐘，讀取數(shù)據(jù)，移位，拉低循環(huán)讀取8位數(shù)據(jù)。

注意，操作完一個(gè)字節(jié)讀取任務(wù)后，時(shí)鐘線還是低電平。

讀取完一個(gè)字節(jié)后，主機(jī)要給從機(jī)發(fā)送一個(gè)應(yīng)答信號(hào)，這樣從機(jī)會(huì)接著發(fā)低字節(jié)數(shù)據(jù)。

6、主機(jī)發(fā)送應(yīng)答信號(hào)給從機(jī)

void I2C_ACK()
{
pinMode(SDIO_PIN, OUTPUT);
digitalWrite(SDIO_PIN, 0);//給從機(jī)發(fā)送應(yīng)答信號(hào)，即拉低數(shù)據(jù)線，然后拉高時(shí)鐘讓從機(jī)讀取該應(yīng)答
digitalWrite(SCLK_PIN, 1);
digitalWrite(SCLK_PIN, 0);//執(zhí)行完應(yīng)答后拉低時(shí)鐘線，準(zhǔn)備下一步動(dòng)作。
}

拉低數(shù)據(jù)線，然后在高電平的時(shí)候讓從機(jī)去讀取，之后拉低時(shí)鐘線準(zhǔn)備下一步接收動(dòng)作。

當(dāng)再接收一個(gè)字節(jié)后，就讀取完成了，這個(gè)時(shí)候就是產(chǎn)生一個(gè)非應(yīng)答信號(hào)，然后發(fā)給總線結(jié)束信號(hào)，告訴從機(jī)一個(gè)讀寫周期結(jié)束了。

7、主機(jī)非應(yīng)答信號(hào)

什么是非應(yīng)答信號(hào)呢？

就是接收完了數(shù)據(jù)，釋放數(shù)據(jù)線，不去拉低數(shù)據(jù)線。

void I2C_NACK()
{
  //非應(yīng)答信號(hào)：即主機(jī)不再對(duì)從機(jī)進(jìn)行應(yīng)答，主機(jī)釋放數(shù)據(jù)線，即拉高數(shù)據(jù)線，然后給時(shí)鐘一個(gè)周期信號(hào)（拉高再拉低）
  pinMode(SDIO_PIN, OUTPUT);
  digitalWrite(SDIO_PIN, 1);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SCLK_PIN, 0);
}

將SDIO引腳設(shè)置為輸出，拉高數(shù)據(jù)線，即為釋放數(shù)據(jù)線，然后拉高拉低時(shí)鐘，即在時(shí)鐘線產(chǎn)生一個(gè)時(shí)鐘周期信號(hào)。

然后發(fā)送結(jié)束信號(hào)。結(jié)束信號(hào)在開頭已經(jīng)講明，即在時(shí)鐘線為高電平的狀態(tài)下，在數(shù)據(jù)線產(chǎn)生一個(gè)上升沿。

觀察以上代碼沒(méi)一個(gè)多余重復(fù)的操作動(dòng)作，即完美的視線了時(shí)序圖上的所有操作。

接下來(lái)就是利用上述的I2C成分進(jìn)行對(duì)寄存器的讀寫操作了。

8、讀寄存器

由于圖中設(shè)備的DeviceID 為0x80，即直接寫進(jìn)來(lái)，從機(jī)判斷是讀還是寫的字節(jié)在寄存器地址。

因此，將寄存器的地址左移一位，在末尾補(bǔ)上是讀（1）還是寫（0）。

uint16_t read_reg(uint8_t reg)
{
  uint16_t dat=0;
  reg=(reg<<1)|1;
  I2C_Start();
  I2C_Write(0x80);
  I2C_RACK();
  I2C_Write(reg);
  I2C_RACK();
  dat=I2C_Read();
  dat=dat<<8;
  I2C_ACK();
  dat=dat|I2C_Read();
  I2C_NACK(); 
  I2C_Stop();
  return dat;
}

9、寫寄存器操作

void write_reg(uint8_t reg, uint16_t dat)
{
  reg=(reg<<1);
  I2C_Start();
  I2C_Write(0x80);
  I2C_RACK();
  I2C_Write(reg);
  I2C_RACK();
  I2C_Write(dat>>8);
  I2C_RACK();
  I2C_Write(dat&0xFF);
  I2C_NACK();
  I2C_Stop();
}

最后，對(duì)寄存器讀寫函數(shù)測(cè)試。

void setup() 
{
  Serial.begin(115200);
  Serial.println("Hello I2C");
  write_reg(0x02,0x2250);
  Serial.println(read_reg(0x02),HEX);
  write_reg(0x02,0x2281);
  Serial.println(read_reg(0x02),HEX);
}


void loop() 
{


}

讀取的數(shù)值與寫入的是一樣的。

最后曬出完整的測(cè)試代碼：

#define SCLK_PIN 8
#define SDIO_PIN 9




void I2C_Start()
{
  //設(shè)置I2C使用的兩個(gè)引腳為輸出模式
  pinMode(SCLK_PIN, OUTPUT);
  pinMode(SDIO_PIN, OUTPUT);


  //在SCL為高電平的時(shí)候讓SDA產(chǎn)生一個(gè)下降沿是為開始信號(hào)
  digitalWrite(SDIO_PIN, 1);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SDIO_PIN, 0);
}


void I2C_Stop()
{
  pinMode(SDIO_PIN, OUTPUT);
  //在SCL為高電平的時(shí)候讓SDA產(chǎn)生一個(gè)上升沿是為停止信號(hào)
  digitalWrite(SDIO_PIN, 0);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SDIO_PIN, 1);
}


void I2C_Write(uint8_t dat)
{
  pinMode(SDIO_PIN, OUTPUT);
  //拉低時(shí)鐘線后可修改數(shù)據(jù)線的狀態(tài)
  digitalWrite(SCLK_PIN, 0); 
  for(int i=0;i<8;i++)
  {
    digitalWrite(SDIO_PIN, (bool)(dat&0x80)); 
    digitalWrite(SCLK_PIN, 1);//在高電平時(shí)候送出數(shù)據(jù)
    dat=dat<<1;
    digitalWrite(SCLK_PIN, 0);//拉低準(zhǔn)備下一個(gè)位的數(shù)據(jù)發(fā)送
  }
}


uint8_t I2C_Read()
{
  uint8_t dat=0;
  pinMode(SDIO_PIN, INPUT);
  for(int i=0;i<8;i++)
  {
    digitalWrite(SCLK_PIN, 1);//讀取數(shù)據(jù)時(shí)候是在時(shí)鐘的高電平狀態(tài)讀取
    dat=dat<<1;
    if(digitalRead(SDIO_PIN))
    {
      dat=dat|1;
    }
    digitalWrite(SCLK_PIN, 0);//拉低時(shí)鐘線準(zhǔn)備下一個(gè)位的讀取
  }
  return dat;
}




bool I2C_RACK()
{
  bool ack;
  pinMode(SDIO_PIN, INPUT);


  digitalWrite(SCLK_PIN, 1);//接收應(yīng)答信號(hào)，當(dāng)時(shí)鐘拉高時(shí)候，從機(jī)送出應(yīng)答信號(hào)
  ack = digitalRead(SDIO_PIN);
  digitalWrite(SCLK_PIN, 0);//讀取完應(yīng)答信號(hào)后拉低時(shí)鐘。
  return ack;
}


void I2C_ACK()
{
  pinMode(SDIO_PIN, OUTPUT);
  digitalWrite(SDIO_PIN, 0);//給從機(jī)發(fā)送應(yīng)答信號(hào)，即拉低數(shù)據(jù)線，然后拉高時(shí)鐘讓從機(jī)讀取該應(yīng)答
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SCLK_PIN, 0);//執(zhí)行完應(yīng)答后拉低時(shí)鐘線，準(zhǔn)備下一步動(dòng)作。
}


void I2C_NACK()
{
  //非應(yīng)答信號(hào)：即主機(jī)不再對(duì)從機(jī)進(jìn)行應(yīng)答，主機(jī)釋放數(shù)據(jù)線，即拉高數(shù)據(jù)線，然后給時(shí)鐘一個(gè)周期信號(hào)（拉高再拉低）
  pinMode(SDIO_PIN, OUTPUT);
  digitalWrite(SDIO_PIN, 1);
  digitalWrite(SCLK_PIN, 1);
  digitalWrite(SCLK_PIN, 0);
}


uint16_t read_reg(uint8_t reg)
{
  uint16_t dat=0;
  reg=(reg<<1)|1;
  I2C_Start();
  I2C_Write(0x80);
  I2C_RACK();
  I2C_Write(reg);
  I2C_RACK();
  dat=I2C_Read();
  dat=dat<<8;
  I2C_ACK();
  dat=dat|I2C_Read();
  I2C_NACK(); 
  I2C_Stop();
  return dat;
}


void write_reg(uint8_t reg, uint16_t dat)
{
  reg=(reg<<1);
  I2C_Start();
  I2C_Write(0x80);
  I2C_RACK();
  I2C_Write(reg);
  I2C_RACK();
  I2C_Write(dat>>8);
  I2C_RACK();
  I2C_Write(dat&0xFF);
  I2C_NACK();
  I2C_Stop();
}




void setup() 
{
  Serial.begin(115200);
  Serial.println("Hello I2C");
  write_reg(0x02,0x2250);
  Serial.println(read_reg(0x02),HEX);
  write_reg(0x02,0x2281);
  Serial.println(read_reg(0x02),HEX);
}


void loop() 
{


}

看完這篇文章，你學(xué)會(huì)純手工擼IO模擬I2C時(shí)序的代碼了嗎？

審核編輯：黃飛